Articolul 8.6 · 17 min de citit

Backup-ul calculatorului cu Windows

Ce salvezi, unde și cum: regula 3-2-1, Istoric fișiere, imaginea de sistem și o copie automată cu robocopy, cu uneltele din Windows și programe gratuite.

Publicat în noiembrie 2026 · Drogoreanu Catalin Gabriel

Coperta capitolului Utilitare

Un SSD se poate defecta fără niciun semn prealabil, un laptop poate fi furat, iar un program de tip ransomware poate cripta în câteva minute toate fișierele la care ajunge. Fotografiile, documentele și tot ce ai lucrat ani de zile rămân doar dacă ai o copie de siguranță (backup), făcută înainte de problemă.

Articolul explică regula după care organizezi copiile, ce merită salvat și cum folosești uneltele incluse în Windows 11 (Istoric fișiere, Windows Backup, imaginea de sistem, unitatea de recuperare), un program gratuit pentru imaginea discului și o copie automată cu robocopy. Pentru site-ul de pe găzduire citește Backup pentru site din cPanel.

Regula 3-2-1

Regula cea mai folosită pentru copiile de siguranță este simplă:

  • 3 copii ale datelor: originalul și încă două copii;
  • 2 tipuri de suport: de exemplu discul din calculator și un disc extern, ca să nu se strice amândouă din aceeași cauză;
  • 1 copie în afara casei: în cloud sau pe un disc ținut în alt loc, pentru incendiu, inundație sau furt.
Fig. 1Regula 3-2-1: trei copii, pe două tipuri de suport, dintre care una în alt loc.

Pentru un calculator de acasă înseamnă de obicei: fișierele pe calculator, o copie automată pe un disc extern și o a doua copie într-un cloud cu istoric de versiuni sau pe un al doilea disc extern, ținut la rude sau la birou și schimbat cu primul o dată pe lună.

Cum afli din timp că un disc se apropie de sfârșit, din valorile SMART, e arătat în articolul 8.10, Sănătatea SSD-ului și a HDD-ului.

Sincronizarea nu este backup

Un folder sincronizat (OneDrive, Google Drive, Dropbox) ține aceeași versiune a fișierelor pe calculator și în cloud. E foarte util când îți strică laptopul, dar nu te apără de propriile greșeli: dacă ștergi un fișier sau îl modifici greșit, sincronizarea copiază imediat și ștergerea, și modificarea. Un ransomware care criptează fișierele de pe calculator le criptează, prin sincronizare, și în cloud.

Un backup cu versiuni păstrează mai multe stări ale aceluiași fișier, de la date diferite. Când observi problema, alegi versiunea de dinainte și o restaurezi.

Fig. 2Aceeași greșeală, cu sincronizare și cu backup cu versiuni.

OneDrive, Google Drive și Dropbox păstrează și ele, limitat, versiunile mai vechi ale unui fișier și fișierele șterse (de obicei 30 de zile, în coșul de reciclare din cloud). E un ajutor bun, dar nu un backup complet: limitele depind de abonament, iar o copie ținută la același furnizor și în același cont nu te apără dacă pierzi accesul la cont.

Ce salvezi și ce nu

Merită salvate datele pe care nu le poți reface:

  • folderele personale: Desktop, Documente, Imagini, Videoclipuri, Muzică și, dacă păstrezi acolo lucruri importante, Descărcări;
  • fotografiile copiate de pe telefon sau de pe aparatul foto;
  • e-mailul păstrat local: profilul Thunderbird (în %APPDATA%\Thunderbird) sau fișierele .pst ale Outlook (de obicei în Documente\Fișiere Outlook);
  • proiectele tale, de exemplu fișierele unui site și o copie a bazei de date;
  • setările unor programe și salvările jocurilor, din %APPDATA% sau din Documente;
  • codurile de recuperare pentru autentificarea în doi pași și o copie criptată a managerului de parole.

Nu e nevoie să salvezi Windows și programele ca fișiere: le reinstalezi. Ca să nu le cauți pe rând, poți păstra lista programelor instalate cu winget, managerul de pachete din Windows. Fișierul rezultat îl pui tot în backup:

winget export -o programe.json
winget import -i programe.json

Prima comandă scrie lista programelor într-un fișier, a doua le instalează pe un calculator nou. Imaginea de sistem, descrisă mai jos, salvează și Windows-ul și programele, dar e utilă pentru altceva: repornirea rapidă după un disc defect.

Dacă te-ai conectat la Windows cu un cont Microsoft, folderele Desktop, Documente și Imagini pot fi mutate în OneDrive. Atunci se află în C:\Users\nume\OneDrive\Documente, nu în C:\Users\nume\Documente. Verifici unde sunt cu clic dreapta pe folder în Explorer → Proprietăți → Locație, înainte să alegi ce salvezi.

Discul extern

  • Capacitatea: cel puțin de două ori cât ocupă datele tale; backupul cu versiuni crește în timp.
  • HDD sau SSD: un HDD extern de 2,5 inci oferă cel mai mult spațiu pe bani și e potrivit pentru copii făcute o dată pe zi sau pe săptămână; un SSD extern e mai rapid și rezistă mai bine la lovituri. Un SSD lăsat nealimentat foarte mult timp (ani) poate pierde date, așa că nu-l folosi ca arhivă uitată într-un sertar.
  • Sistemul de fișiere: pentru backup din Windows formatezi discul NTFS. exFAT e util doar dacă discul trebuie citit și pe un Mac sau pe un televizor.
  • Conectat doar cât durează backupul: un disc lăsat permanent în calculator poate fi criptat de ransomware odată cu restul. După copiere, îl scoți în siguranță și îl deconectezi.
  • Criptarea: dacă discul conține documente personale și poate fi pierdut sau furat, îl criptezi. Windows Pro are BitLocker To Go (clic dreapta pe disc → Activare BitLocker); pe Windows Home poți folosi programul gratuit VeraCrypt. Cheia de recuperare o păstrezi separat, altfel nici tu nu mai poți citi copia.

Istoric fișiere: copii automate, cu versiuni

Istoric fișiere (File History) e unealta din Windows cea mai potrivită pentru copia de zi cu zi. Copiază automat folderele tale pe un disc extern, la intervalul ales (implicit o dată pe oră), și păstrează versiunile mai vechi ale fiecărui fișier.

Pornirea

  1. Conectezi discul extern.
  2. Deschizi Panoul de control (scrii „panou de control” în căutarea din bara de activități) → Sistem și securitate → Istoric fișiere. În Windows 11 nu apare în Setări, doar în Panoul de control.
  3. Dacă discul nu e ales deja, apeși Selectare unitate și îl alegi.
  4. Apeși Activare (Turn on). Prima copiere durează mai mult; următoarele copiază doar fișierele modificate.

În Setări complexe (Advanced settings) alegi cât de des se face copia (de la 10 minute la o dată pe zi) și cât timp se păstrează versiunile (Pentru totdeauna sau Până când este necesar spațiu, care șterge versiunile cele mai vechi când discul se umple). Tot acolo, Curățare versiuni șterge manual versiunile mai vechi de o anumită vârstă.

Ce salvează

Istoric fișiere salvează folderele din biblioteci (Documente, Muzică, Imagini, Videoclipuri), Desktop-ul, Contactele și Favoritele. Un folder exclus îl adaugi la Excludere foldere. Un folder în plus, de exemplu D:\Proiecte, îl incluzi într-o bibliotecă: în Explorer, clic dreapta pe folder → Afișare mai multe opțiuni → Includere în bibliotecă → Documente.

Recuperarea unui fișier

  • pentru un fișier sau un folder anume: clic dreapta pe el în Explorer → Proprietăți → fila Versiuni anterioare (Previous Versions); alegi data și apeși Restaurare sau, ca să nu suprascrii fișierul actual, Restaurare în alt loc;
  • pentru o căutare prin toate copiile: în fereastra Istoric fișiere apeși Restaurare fișiere personale (Restore personal files), te deplasezi între date cu săgețile de jos, selectezi ce îți trebuie și apeși butonul verde.

Dacă discul nu e conectat, copiile se opresc, iar Windows te avertizează după o vreme. Când îl conectezi din nou, Istoric fișiere continuă singur.

Windows Backup: setările și folderele în OneDrive

Aplicația Windows Backup din Windows 11 (o găsești în meniul Start) salvează în contul tău Microsoft folderele Desktop, Documente, Imagini (și, opțional, Muzică și Videoclipuri), lista aplicațiilor, setările (fundal, limbă, accesibilitate) și parolele Wi-Fi. La instalarea unui calculator nou, cu același cont, Windows îți propune să le aduci înapoi.

E comod, dar nu înlocuiește un backup pe disc: folderele ajung, de fapt, sincronizate în OneDrive, cu limitele descrise mai sus, iar spațiul gratuit de 5 GB se umple repede cu fotografii. Folosește-l pentru setări și ca a doua copie, nu ca singură copie.

Imaginea de sistem și unitatea de recuperare

O imagine de sistem e o copie a întregului disc: Windows, programe, setări și fișiere. Când SSD-ul se defectează, montezi unul nou, restaurezi imaginea și calculatorul arată exact ca la data copiei, fără reinstalări. E bine să faci una după ce ai instalat și configurat totul, apoi o dată la câteva luni.

Varianta din Windows

Windows 11 are încă vechea unealtă: Panoul de control → Sistem și securitate → Backup și restaurare (Windows 7) → Crearea unei imagini de sistem (Create a system image), cu imaginea salvată pe discul extern. Funcționează, dar Microsoft nu o mai dezvoltă și o poate scoate într-o versiune viitoare. Păstrează cel puțin o singură imagine, fără versiuni.

Programe gratuite

  • Veeam Agent for Microsoft Windows FREE: face imagini ale discului sau copii ale folderelor, programate, cu copii incrementale (după prima copie completă, doar modificările), și creează un stick de pornire pentru restaurare.
  • Clonezilla: pornește de pe un stick USB, în afara Windows-ului, și face imaginea întregului disc pe un disc extern. Lucrează în mod text, cu meniuri și întrebări pe rând. E potrivit pentru o imagine făcută manual, din când în când.
  • Rescuezilla: se prezintă pe site-ul său drept interfața grafică (GUI) pentru Clonezilla, compatibilă complet cu acesta: o imagine făcută cu Clonezilla se restaurează cu Rescuezilla și invers. Pornește tot de pe un stick USB, dar lucrezi cu mouse-ul, în ferestre. Are și funcții pe care Clonezilla nu le oferă: un explorator de imagini (încă în test, lent la imaginile comprimate), cu care deschizi o imagine și scoți din ea un singur fișier fără să restaurezi tot discul; restaurarea imaginilor de mașini virtuale (VirtualBox, VMware, Hyper-V, QEMU) și a imaginilor brute (.img, .dd); un editor de partiții, acces la internet cu browser și un program pentru recuperarea fișierelor șterse. Pentru cine nu a mai lucrat cu astfel de programe, e varianta mai ușoară.

Cum pui Clonezilla, Rescuezilla și alte unelte pe același stick, alături de instalarea Windows, e arătat în articolul 8.9, Stick bootabil cu Ventoy.

Macrium Reflect Free, mult timp recomandat pentru imagini de disc, nu mai primește actualizări din 2024. Pentru o instalare nouă alege un program întreținut în continuare.

Unitatea de recuperare

O imagine se restaurează pornind calculatorul de pe un stick. Pregătește-l acum, cât calculatorul merge: scrii „unitate de recuperare” în căutare → Creare unitate de recuperare (Create a recovery drive), alegi un stick de cel puțin 16 GB (tot ce e pe el se șterge) și urmezi pașii. Pornit de pe stick, la Depanare → Opțiuni complexe găsești și Recuperarea imaginii de sistem. Programele de mai sus au propriul stick de pornire.

La restaurarea unei imagini, discul calculatorului e suprascris complet. Fișierele modificate după data imaginii le aduci apoi din Istoric fișiere.

Copie automată cu robocopy

Dacă vrei să controlezi exact ce se copiază, poți folosi robocopy, programul de copiere din linia de comandă inclus în Windows. Copiază doar fișierele noi sau modificate, așa că a doua rulare durează puțin. Fișierul de mai jos îl salvezi ca backup.bat (în Notepad, cu Salvare ca → Toate fișierele):

@echo off
rem Copie de siguranta pe un disc extern sau pe un disc din retea, cu robocopy
rem Unde se face copia: un singur rand DEST ramane fara rem in fata
rem - disc extern:
set "DEST=E:\Backup-PC"
rem - NAS sau folder partajat in retea:
rem set "DEST=\\NAS\Backup\PC"
set "SURSA=%USERPROFILE%"
rem Ce sari la toate folderele: foldere dupa /XD, fisiere dupa /XF
set "EXCLUDE=/XD node_modules .git /XF *.tmp *.iso desktop.ini"

if not exist "%DEST%\" (
  echo Discul de backup (sau NAS-ul) nu este disponibil sau lipseste folderul %DEST%.
  pause
  exit /b 1
)

set EROARE=0
rem Cate un folder pe rand: sursa, numele copiei, optional tipurile de fisiere.
rem Un rand care incepe cu rem nu se mai executa.
call :copiaza "%SURSA%\Desktop"   "Desktop"
call :copiaza "%SURSA%\Documents" "Documents"
call :copiaza "%SURSA%\Pictures"  "Pictures"
call :copiaza "%SURSA%\Videos"    "Videos"
rem call :copiaza "%SURSA%\Music" "Music"
call :copiaza "D:\Proiecte"       "D-Proiecte"
call :copiaza "D:\Fotografii"     "D-Fotografii" *.jpg *.jpeg *.png *.heic

title Backup: gata
if %EROARE%==1 (echo Unele fisiere nu s-au copiat. Vezi %DEST%\backup.log) else (echo Gata.)
pause
exit /b

:copiaza
title Backup: copiez %~2 ...
echo.
echo === Copiez %~1 ===
if not exist "%~1\" (
  echo Lipseste %~1, sar peste el.
  >>"%DEST%\backup.log" echo Lipseste %~1
  goto :eof
)
robocopy "%~1" "%DEST%\%~2" %3 %4 %5 %6 %7 %8 %9 /E /XJ /FFT /R:1 /W:1 /NP /TEE %EXCLUDE% /LOG+:"%DEST%\backup.log"
if errorlevel 8 set EROARE=1
goto :eof

Ce copiezi și ce sari

Fiecare folder salvat are rândul lui, de forma call :copiaza "sursa" "nume". Rândurile apelează aceeași secțiune de la sfârșitul fișierului, :copiaza, care rulează robocopy. Așa modifici lista fără să atingi comanda:

  • Un folder din profilul tău (C:\Users\nume) se scrie cu %SURSA% în față: "%SURSA%\Downloads". Numele folderelor sunt cele reale, în engleză (Documents, Pictures), chiar dacă Explorer le afișează în română.
  • Un folder de pe alt disc se scrie cu calea întreagă: "D:\Proiecte". Al doilea nume, "D-Proiecte", e folderul creat în copie; îl alegi tu, dar trebuie să fie diferit pentru fiecare rând, altfel două foldere ajung în același loc.
  • Un folder pe care nu-l mai vrei îl dezactivezi scriind rem la începutul rândului, ca la Music în exemplu. Ștergi rem și folderul se copiază din nou.
  • Doar anumite tipuri de fișiere: scrii extensiile la sfârșitul rândului, ca la D:\Fotografii, unde se copiază doar fotografiile. Fără extensii se copiază tot.
  • Ce sari la toate folderele se scrie o singură dată, în EXCLUDE: după /XD numele folderelor (aici node_modules și .git, care pot avea zeci de mii de fișiere), după /XF fișierele sau tipurile de fișiere. Dacă nu vrei să sari nimic, lași set "EXCLUDE=".
  • Un folder care lipsește (de exemplu discul D: nu există pe alt calculator) nu oprește copia: scriptul îl sare și îl notează în jurnal.

Ce vezi pe ecran cât lucrează

  • Bara de titlu a ferestrei arată folderul copiat în acel moment („Backup: copiez Documents ...”), iar la final „Backup: gata”. Se vede și pe bara de activități, dacă minimizezi fereastra.
  • Fiecare folder începe cu un rând === Copiez ... ===, urmat de fișierele copiate, pe măsură ce sunt copiate, și de un sumar: câte fișiere au fost copiate, sărite sau au dat erori și cât a durat.
  • La final apare „Gata.” sau mesajul de eroare și „Apăsați o tastă pentru a continua”. Abia atunci copia s-a terminat.
  • Un fișier foarte mare, de exemplu un film, poate ține ecranul nemișcat câteva zeci de secunde; titlul ferestrei arată că scriptul încă lucrează.

Ce înseamnă opțiunile lui robocopy:

OpțiuneaCe face
/Ecopiază și subfolderele, inclusiv cele goale; nu șterge nimic din copie
/XJsare peste legăturile speciale din profilul Windows (de exemplu „My Music” din Documente), care altfel produc erori sau copieri în buclă
/FFTcompară datele fișierelor cu o toleranță de 2 secunde, necesară pe discurile exFAT sau FAT32 și utilă pe multe NAS-uri
/R:1 /W:1la un fișier blocat (deschis de un program) încearcă o singură dată, după o secundă, în loc de reîncercările implicite (un milion, la câte 30 de secunde)
/NPnu afișează procentul copiat din fiecare fișier, care ar umple jurnalul cu rânduri inutile
/XDsare peste folderele cu numele date, oriunde s-ar afla în sursă
/XFsare peste fișierele cu numele sau extensiile date (*.tmp)
/TEEafișează rezultatul și în fereastră, nu doar în jurnal
/LOG+:adaugă rezultatul în fișierul jurnal, fără să-l șteargă pe cel vechi

Câteva lucruri de știut:

  • Litera discului (E:) o vezi în Explorer, la Acest PC. Windows poate da altă literă dacă mai conectezi un stick; în Gestionare disc (clic dreapta pe Start) îi poți fixa o literă, de exemplu B:, rar folosită.
  • Dacă folderele tale sunt în OneDrive (vezi mai sus), înlocuiești %USERPROFILE% cu %OneDrive%. Fișierele OneDrive păstrate doar online se descarcă atunci când robocopy le citește.
  • robocopy întoarce coduri de la 0 la 7 când copierea a reușit și 8 sau mai mult când au apărut erori; de aceea scriptul verifică if errorlevel 8.
  • Cu /E, un fișier șters de pe calculator rămâne în copie. Opțiunea /MIR face o copie identică și șterge din copie ce ai șters de pe calculator, deci transformă backupul într-o sincronizare. Nu o folosi pentru singura copie.
  • Copia nu are versiuni: un fișier modificat greșit îl înlocuiește pe cel bun la următoarea rulare. Pentru versiuni folosești Istoric fișiere sau Veeam; scriptul e util ca a doua copie sau pentru foldere pe care celelalte unelte nu le salvează.

Rularea automată

Ca să ruleze singur, de exemplu în fiecare seară, îl adaugi în Task Scheduler (Planificator de activități): Creare activitate de bază, alegi Zilnic și ora, apoi Pornire program și calea fișierului backup.bat. Pentru rularea automată scoate cele două linii pause, ca fereastra să nu aștepte o tastă. Dacă discul nu e conectat, scriptul se oprește singur, fără să copieze nimic. Comenzile din fișierele .bat, pauzele și capcanele lor sunt explicate în articolul 8.12, Fișiere .bat: comenzile uzuale.

Backup pe un NAS sau pe un disc din rețea

Același script copiază și pe un NAS, pe un folder partajat de pe alt calculator sau pe discul USB legat la router. Pui rem în fața rândului cu discul extern și îl scoți din fața rândului cu rețeaua:

rem set "DEST=E:\Backup-PC"
set "DEST=\\NAS\Backup\PC"
  • Calea are forma \\numele-NAS-ului\partajarea\folder sau, cu adresa IP, \\192.168.1.20\Backup\PC. Folderul din capăt (aici PC) îl creezi o dată, din Explorer. Verificarea de la începutul scriptului merge și pe rețea: dacă NAS-ul e oprit sau laptopul e în altă rețea, scriptul se oprește fără să copieze nimic.
  • Calea completă, nu o literă de unitate mapată (Z:): literele mapate există doar în sesiunea în care le-ai creat, iar pornit din Task Scheduler sau „ca administrator”, scriptul poate să nu le vadă.
  • Parola partajării nu se scrie în script. O salvezi o dată în Windows, cu o comandă care ți-o cere fără s-o afișeze:
    cmdkey /add:NAS /user:numele-tau-de-pe-NAS /pass
    Numele de după /add: trebuie să fie exact cel din cale (NAS sau 192.168.1.20). Același lucru se face din Panou de control → Manager de acreditări → Acreditări Windows. Ca test, rulezi dir \\NAS\Backup: dacă vezi conținutul, scriptul are acces. Acreditările sunt ale utilizatorului tău, așa că în Task Scheduler lași activitatea să ruleze doar când ești conectat.
  • Viteza: prin cablu, copia merge aproape ca pe un disc extern; pe Wi-Fi, prima copie poate dura ore. Pentru foldere cu foarte multe fișiere mici poți adăuga /MT:8 pe rândul cu robocopy (copiază 8 fișiere deodată); rândurile din fereastră și din jurnal apar atunci amestecate.
  • NAS-ul trebuie să știe SMB 2 sau 3. Windows 11 nu mai folosește vechiul SMB 1; dacă un NAS sau un router foarte vechi îl cere, nu activa SMB 1 în Windows, ci actualizează sau schimbă aparatul.
  • Ransomware: o partajare la care calculatorul ajunge oricând poate fi criptată odată cu el, ca un disc extern lăsat conectat. Te ajută instantaneele (snapshots) sau coșul de reciclare al partajării, dacă NAS-ul le are, un utilizator separat doar pentru backup și, în continuare, o copie pe un disc deconectat.
  • NAS-ul din casă nu e copia „din afara casei” din regula 3-2-1: la incendiu sau furt se pierde odată cu calculatorul.

Copia din afara casei

  • Un serviciu de backup în cloud (de exemplu Backblaze sau IDrive) copiază automat folderele alese și păstrează versiunile și fișierele șterse o perioadă stabilită. E varianta cea mai comodă, cu abonament plătit.
  • Un cloud obișnuit cu istoric de versiuni (OneDrive, Google Drive, pCloud), cu limitele de la sincronizare: e mai bun decât nimic, mai ales dacă păstrezi acolo o arhivă criptată, făcută periodic.
  • Un al doilea disc extern, ținut la rude sau la birou: o dată pe lună îl aduci, faci copia și îl duci înapoi. Nu costă abonament, dar copia e atât de nouă cât ultima ta vizită.

Orice copie ținută la altcineva sau în cloud trebuie să fie criptată: disc cu BitLocker sau VeraCrypt, arhivă 7-Zip cu parolă (AES-256), sau un serviciu care criptează fișierele înainte să le trimită.

Ce te salvează în fiecare situație

Tabelul e lat; pe telefon îl derulezi spre dreapta.

MetodaCe salveazăCât de desFișier șters sau stricatDisc defectRansomwareFurt, incendiu
Istoric fișierefolderele personale, cu versiuniautomat, la orădadada, dacă discul era deconectatnu
Imagine de sistemtot disculla câteva lunidoar fișierele de la data imaginiida, cel mai rapidda, dacă discul era deconectatnu
robocopy /Efolderele alese, fără versiunizilnic sau manualdoar dacă nu a rulat între timpdada, dacă discul era deconectatnu
Windows Backup / OneDrivefolderele și setărilecontinuuparțial, din coșul și versiunile OneDrivedaparțialda
Backup în cloud sau disc la rudefolderele alese, cu versiunizilnic / lunardadadada

Testează restaurarea

Un backup pe care nu l-ai încercat niciodată poate să nu funcționeze exact când ai nevoie de el: discul s-a umplut de luni de zile, folderul important nu era inclus, parola arhivei s-a pierdut. Fă un test simplu o dată pe lună: alege un fișier, restaurează-l într-un alt folder din copie și deschide-l. O dată pe an, verifică și că stick-ul de recuperare pornește calculatorul.

Lista de verificare

  1. Știi unde sunt folderele tale (local sau în OneDrive) și ce vrei să salvezi.
  2. Ai un disc extern formatat NTFS, de cel puțin două ori cât datele, criptat dacă poate fi pierdut.
  3. Istoric fișiere e pornit, cu discul extern, iar copia se face cel puțin zilnic.
  4. Ai o imagine de sistem recentă și o unitate de recuperare pe stick.
  5. Ai o copie criptată în afara casei: cloud cu versiuni sau un al doilea disc la altcineva.
  6. Discul de backup e conectat doar cât durează copia.
  7. Ai lista programelor (winget export), codurile de recuperare și cheile BitLocker într-un loc sigur, în afara calculatorului.
  8. O dată pe lună restaurezi un fișier ca test.

Pentru site-ul de pe internet, regula e aceeași, cu alte unelte: citește Backup pentru site din cPanel. Despre copierea fișierelor site-ului de pe calculator pe server găsești detalii în FTP.

Toate articolele despre securitate, grupate pe teme, sunt în capitolul 18, Securitate.